MQL4のチャート操作関数｜ChartSetIntegerとChartScreenShotの使い方・エラー番号をMT4で確かめた

void ShowInfo()
	{
	 long id = ChartID();
	 Print("[info] ChartID=", id);
	 Print("[info] visible bars: ", ChartGetInteger(id, CHART_VISIBLE_BARS),
				 " / WindowBarsPerChart=", WindowBarsPerChart());
	 Print("[info] first visible bar: ", ChartGetInteger(id, CHART_FIRST_VISIBLE_BAR),
				 " / WindowFirstVisibleBar=", WindowFirstVisibleBar());
	 Print("[info] windows: ", ChartGetInteger(id, CHART_WINDOWS_TOTAL),
				 " / WindowsTotal=", WindowsTotal());
	 Print("[info] handle: ", ChartGetInteger(id, CHART_WINDOW_HANDLE),
				 " / WindowHandle=", WindowHandle(Symbol(), Period()));
	 Print("[info] WindowHandle(USDJPY, M5)=", WindowHandle("USDJPY", PERIOD_M5));
	 Print("[info] size: ", ChartGetInteger(id, CHART_WIDTH_IN_PIXELS), " x ",
				 ChartGetInteger(id, CHART_HEIGHT_IN_PIXELS));
	 Print("[info] mode=", ChartGetInteger(id, CHART_MODE), " scale=", ChartGetInteger(id, CHART_SCALE),
				 " shift=", ChartGetInteger(id, CHART_SHIFT), " grid=", ChartGetInteger(id, CHART_SHOW_GRID));
	}

void ShowPrice()
	{
	 long id = ChartID();
	 Print("[price] ChartGetDouble min/max=", DoubleToString(ChartGetDouble(id, CHART_PRICE_MIN), Digits),
				 " / ", DoubleToString(ChartGetDouble(id, CHART_PRICE_MAX), Digits),
				 " WindowPriceMin/Max=", DoubleToString(WindowPriceMin(), Digits),
				 " / ", DoubleToString(WindowPriceMax(), Digits));
	}

void ChangeAndShoot()
	{
	 long id = ChartID();
	 ChartScreenShot(id, "mql4chart_before.png", 1000, 560);
	 Sleep(1500); // the screenshot is queued, wait for it
	 ChartSetInteger(id, CHART_MODE, CHART_CANDLES);
	 ChartSetInteger(id, CHART_SHOW_GRID, false);
	 ChartSetInteger(id, CHART_SHIFT, true);
	 ChartSetInteger(id, CHART_SCALE, 3);
	 ChartSetInteger(id, CHART_COLOR_BACKGROUND, clrWhite);
	 ChartSetInteger(id, CHART_COLOR_FOREGROUND, clrBlack);
	 ChartSetInteger(id, CHART_COLOR_CANDLE_BULL, clrBlue);
	 ChartSetInteger(id, CHART_COLOR_CANDLE_BEAR, clrRed);
	 Print("[set] mode right after set=", ChartGetInteger(id, CHART_MODE),
				 " bg right after set=", ChartGetInteger(id, CHART_COLOR_BACKGROUND));
	 ChartRedraw(id);
	 Sleep(1500);
	 ChartScreenShot(id, "mql4chart_after.png", 1000, 560);
	 Sleep(1500);
	}

long FileBytes(string name)
	{
	 int h = FileOpen(name, FILE_READ | FILE_BIN);
	 if(h == INVALID_HANDLE)
			return -1;
	 long n = (long)FileSize(h);
	 FileClose(h);
	 return n;
	}

void ShotFormats()
	{
	 long id = ChartID();
	 string names[5] = {"mql4chart_a.gif", "mql4chart_a.png", "mql4chart_a.bmp", "mql4chart_a.txt", "mql4chart_w.gif"};
	 Print("[shot] ChartScreenShot gif=", ChartScreenShot(id, names[0], 640, 360),
				 " png=", ChartScreenShot(id, names[1], 640, 360),
				 " bmp=", ChartScreenShot(id, names[2], 640, 360),
				 " txt=", ChartScreenShot(id, names[3], 640, 360));
	 Print("[shot] WindowScreenShot gif=", WindowScreenShot(names[4], 640, 360),
				 " png=", WindowScreenShot("mql4chart_w.png", 640, 360));
	 Sleep(2500);
	 for(int i = 0; i < 5; i++)
			Print("[shot] ", names[i], " bytes=", FileBytes(names[i]));
	 Print("[shot] mql4chart_w.png bytes=", FileBytes("mql4chart_w.png"));
	}

int CountCharts()
	{
	 int n = 0;
	 for(long c = ChartFirst(); c >= 0; c = ChartNext(c))
			n++;
	 return n;
	}

void ChartsDemo()
	{
	 Print("[open] charts before=", CountCharts());
	 ResetLastError();
	 long nid = ChartOpen("EURUSD", PERIOD_H4);
	 int err = GetLastError();
	 Print("[open] ChartOpen id=", nid, " err=", err, " charts=", CountCharts());
	 Sleep(1000);
	 Print("[open] new chart: ", ChartSymbol(nid), " / ", ChartPeriod(nid));
	 Print("[open] ChartSetSymbolPeriod ret=", ChartSetSymbolPeriod(nid, "EURUSD", PERIOD_D1));
	 Sleep(1000);
	 Print("[open] after change: ", ChartSymbol(nid), " / ", ChartPeriod(nid));
	 Print("[open] ChartClose ret=", ChartClose(nid));
	 Sleep(1000);
	 Print("[open] charts after close=", CountCharts());
	}

void SubDemo()
	{
	 long nid = ChartOpen("EURUSD", PERIOD_H1);
	 Sleep(1500);
	 Print("[sub] new chart windows=", ChartGetInteger(nid, CHART_WINDOWS_TOTAL));
	 ResetLastError();
	 bool ok = ChartApplyTemplate(nid, "Momentum.tpl");
	 int err = GetLastError();
	 int total = (int)ChartGetInteger(nid, CHART_WINDOWS_TOTAL);
	 Print("[sub] ChartApplyTemplate ret=", ok, " err=", err, " windows=", total);
	 Print("[sub] ChartIndicatorName(sub1)=", ChartIndicatorName(nid, 1, 0));
	 Print("[sub] ChartWindowFind(Momentum(8))=", ChartWindowFind(nid, "Momentum(8)"),
				 " missing=", ChartWindowFind(nid, "NoSuchIndicator"));
	 Print("[sub] YDISTANCE_1=", ChartGetInteger(nid, CHART_WINDOW_YDISTANCE, 1));
	 for(int w = 0; w < total; w++)
			Print("[sub] window ", w, " indicators=", ChartIndicatorsTotal(nid, w));
	 ChartClose(nid);
	}

void TestErrors()
	{
	 long id = ChartID();
	 ResetLastError();
	 bool ok = ChartSetInteger(id, (ENUM_CHART_PROPERTY_INTEGER)9999, 1);
	 Print("[err] unknown property: ret=", ok, " err=", GetLastError());
	 ResetLastError();
	 ok = ChartSetInteger(id, CHART_WINDOWS_TOTAL, 2);
	 Print("[err] read-only property: ret=", ok, " err=", GetLastError());
	 ResetLastError();
	 ok = ChartSetInteger(123456789, CHART_MODE, CHART_LINE);
	 Print("[err] bad chart id: ret=", ok, " err=", GetLastError());
	 ResetLastError();
	 long nid = ChartOpen("NOSUCHSYM", PERIOD_H1);
	 Print("[err] ChartOpen bad symbol: id=", nid, " err=", GetLastError());
	}